home *** CD-ROM | disk | FTP | other *** search
/ TOS Silver 2000 / TOS Silver 2000.iso / Anwendun / Pov / POV302 / SCENES / LEVEL2 / PACMAN.POV < prev    next >
Encoding:
Text File  |  1996-07-08  |  3.0 KB  |  162 lines
  1. /*
  2.  * pacman.pov
  3.  *
  4.  * POV-Ray 3.0 scene description for Pac Man doing his favourite job
  5.  *
  6.  * Copyright (c) 1991, 1996 Ville Saari
  7.  *
  8.  * Created: 03-Jan-91
  9.  * Updated: 02-Jul-96
  10.  *
  11.  * Needs image map file "maze.iff"
  12.  *
  13.  * Author:
  14.  *
  15.  *   Ville Saari
  16.  *   Tallbergin puistotie 7 B 21
  17.  *   00200 Helsinki
  18.  *   FINLAND
  19.  *
  20.  *   EMail: vs@iki.fi
  21.  */
  22.  
  23. global_settings { assumed_gamma 1 }
  24.  
  25. camera { location <-80, 35, -140> look_at <40, 10, 0> }
  26. light_source { <60, 120, -170> rgb 1 }
  27.  
  28. default { finish { ambient .08 diffuse .92 } }
  29.  
  30. plane // The maze-textured ground
  31.    {
  32.    y, 0
  33.  
  34.    pigment
  35.       {
  36.       image_map { iff "maze.iff" }
  37.       quick_colour rgb <0, 0, 08>
  38.       rotate x*90
  39.       scale 1600
  40.       translate <-196, 0, 160>
  41.       }
  42.  
  43.    finish { reflection .5 }
  44.    }
  45.  
  46. union // Pac Man
  47.    {
  48.    intersection // Body
  49.       {
  50.       sphere { 0, 30 }
  51.       sphere { 0, 28 inverse }
  52.  
  53.       union
  54.          {
  55.          plane { y, 0 rotate -35*x }
  56.          plane { -y, 0 rotate 10*x }
  57.          }
  58.  
  59.       sphere { -29*z, 1.5 inverse rotate <16, -4, 0> }
  60.       sphere { -29*z, 1.5 inverse rotate <16, 4, 0> }
  61.  
  62.       pigment { rgb <.83, .67, 0> }
  63.       finish { specular .5 roughness .1 }
  64.       }
  65.  
  66.    intersection // Mouth
  67.       {
  68.       sphere { 0, 28 }
  69.  
  70.       union
  71.          {
  72.          plane { y, -2 rotate -35*x }
  73.          plane { -y, -2 rotate 10*x }
  74.          }
  75.    
  76.       pigment { rgb <.29, 0, 0> }
  77.       finish { ambient .05 diffuse .95 }
  78.       }
  79.    
  80.    union // Tongue
  81.       {
  82.       sphere { <3, 0, -15>, 10 }
  83.       sphere { <-3, 0, -15>, 10 }
  84.  
  85.       rotate -45*x
  86.  
  87.       pigment { rgb <1, 0, 0> }
  88.       normal { wrinkles .5 scale .5 }
  89.       finish { reflection .5 }
  90.       }
  91.  
  92.    union // Right eye
  93.       {
  94.       union
  95.          {
  96.          sphere { 0, 6 pigment { rgb 1 } }
  97.          sphere { -2.3*z, 4 pigment { rgb <.11, .19, .67> } }
  98.          sphere { -5.5*z, 1 pigment { rgb 0 } }
  99.  
  100.          finish { reflection .5 }
  101.          }
  102.  
  103.       sphere
  104.          {
  105.          0, 1
  106.  
  107.          scale <9, 2, 9>
  108.          translate <0, 8, 6>
  109.          rotate -10*z
  110.  
  111.          pigment { rgb 0 }
  112.          }
  113.    
  114.       rotate <-25, -20, 0>
  115.       translate -26*z
  116.       rotate <25, 20, 0>
  117.       }
  118.  
  119.    union // Left eye
  120.       {
  121.       union
  122.          {
  123.          sphere { 0, 6 pigment { rgb 1 } }
  124.          sphere { -2.3*z, 4 pigment { rgb <.11, .19, .67> } }
  125.          sphere { -5.5*z, 1 pigment { rgb 0 } }
  126.  
  127.          finish { reflection .5 }
  128.          }
  129.  
  130.       sphere
  131.          {
  132.          0, 1
  133.  
  134.          scale <9, 2, 9>
  135.          translate <0, 8, 6>
  136.          rotate 10*z
  137.  
  138.          pigment { rgb 0 }
  139.          }
  140.    
  141.       rotate <-25, 20, 0>
  142.       translate -26*z
  143.       rotate <25, -20, 0>
  144.       }
  145.  
  146.    translate 32*y
  147.    }
  148.  
  149. // Food
  150.  
  151. union
  152.    {
  153.    sphere { <0, 27, -25>, 4 }
  154.    sphere { <0, 27, -45>, 4 }
  155.    sphere { <0, 27, -65>, 4 }
  156.    sphere { <0, 27, -85>, 4 }
  157.    sphere { <0, 27, -105>, 4 }
  158.  
  159.    pigment { rgb 1 }
  160.    finish { specular 2 roughness .01 reflection .6 }
  161.    }
  162.